Using indexed colors with the PLOT function

Topic:

You may want plot multiple sets of data on the same axis with different indexed colors. You can complete this task with Direct Graphics using the PLOT, and OPLOT procedures. If you want produce a high qualitly interactive version of this plot, you can do this using IDL 8 Graphics using the PLOT function with the RGB_TABLE and VERT_COLORS keywords. This article provides an example of how this can be done. 

Discussion:

If you are using Direct Graphics, you over-plot a series of plots with different indexed colors using the PLOT and OPLOT procedure. An example of how this can be done is shown below:

pro dg_index_colors_example

   compile_opt idl2

   x= findgen(10)
   y= x*x
  
   device,DECOMPOSED=0
   loadct,39
   plot,x,y,xrange=[0,20]

   for i=0,9 do begin
     oplot,x+i,y+i,color=25*i
   endfor

end

If you want to complete the same task using the PLOT function it can be done using the RGB_TABLE, VERT_COLORS, and OVERPLOT keywords. An example of how this can be done is shown below:

 pro vert_colors_example
 compile_opt idl2

  x= findgen(10)
  y= x*x
  p = plot(x,y,RGB_TABLE=39)
 
  for i = 0L, 9 do begin
   op = plot(x+i,y+i,RGB_TABLE=39,VERT_COLORS=[25*i],/OVERPLOT)
  endfor

end

Written by DS and reviewed by JU (9/4/2014)