IDL's Lambda Function Examples

The Lamba function concept was introduced in IDL 8.4. I found that using a Lambda function can result in fewer lines of code and save coding time. However, IDL's Lambda function does not create the most optimal code. Although in my experience, the same is also true for other languages. While the syntax can look very short and concise, the execution time and memory use is not optimal.

Here are some examples of using a Lambda function in conjunction with Map, Filter, Reduce, as well as the FOR loop versions for comparison.

First create some data to use for the remainder of the examples.

 ;Create some test data in a string array of 1400 lines

 ;containing various comma separated numbers

 str = strjoin(strtrim(fix(bindgen(8,1400)),2),',')

This is an example of splitting all the strings on the commas using Map.

 ;split on comma and place the result in another array

 a = str.map(lambda(x:x.split(',')))

 

 ;exactly the same result using a loop

 b = strarr(8,1400)

 for j=0,1399 do b[0,j] = str[j].split(',')

 

The next example is using Filter to return only strings that have a '10' in the 3rd column:

 ;Filter to only keep lines with '10' in 3rd column

 c = str.filter(lambda(x:(x.split(','))[2] eq '10'))

 

 ;Use For and list

 d = list()

 for j=0,1399 do if (str[j].split(','))[2] eq '10' then d.Add, str[j]

 d = d.ToArray()

The final example uses Reduce to return the maximum of the individual totals for each string:

 ;Use Reduce to find the maximum total

 m = str.reduce(lambda(x,y:isa(x,/string)?total(long(x.split(',')))>total(long(y.split(','))):x>total(long(y.split(',')))))

 

 ;Using for loop

 maxtot = -999

 for j=0,999 do begin

   tot = total(long(str[j].split(',')))

   if tot gt maxtot then maxtot = tot

  endfor