Object graphics is great for those that want a high level of control when creating and manipulating graphics. You can create individual shapes and figures, place them in to scalable and rotatable models, then place any number of those models into the view. This allows for both discrete and high level control over all of the elements in your graphics scene.
IDL graphics is excellent for plotting data in a variety of ways including scatterplots, histograms, and bubbleplots. These graphics have methods on them that allow you to copy the graphics window to a variable, save the graphic to various file formats, or change the properties of the graphic using keywords.
Both of these methods have their own strengths, so how would one go about combining them to take advantage of both? Luckily, IDL is set up so that this is pretty easy.
An IDL graphics window is interchangeable with a object graphics view (IDLgrView). In the example below I show how you can create a graphics model, then place it in to an IDL graphics window. Since we are using the two graphic packages together, it is now easy to rotate, scale, and change the properties of the object graphics hierarchy, as well as use the methods and properties that come with new graphics.
Just don't forget to use the Refresh method to update your display after making your changes!
pro grahpics_mixing
compile_opt idl2
;Create a polygon graphics atom and add it to a model.
x = [-0.8, 0.0, 0.8]
y = [-sqrt(3)/3, sqrt(2)/2, -sqrt(3)/3]
oPoly = IDLgrPolygon(x, y)
oModel = IDLgrModel()
oModel.Add, oPoly
;Create the display window, add the model and refresh.
win = WINDOW(WINDOW_TITLE="My Window", $
DIMENSIONS=[600,400])
win.Add, oModel
win.Refresh
;Rotate the model, which in turn rotates the polygon.
for i=0, 179 do begin
oModel.Rotate, [0, 0, 1], 2
win.Refresh
endfor
;Create a video object and add a video stream to save the next part
; to an mp4.
vid = IDLffVideoWrite('video.mp4', format='mp4')
framerate = 24
dims = win.dimensions
stream = vid.addvideostream(dims[0],dims[1],framerate,codec='mpeg4')
;Rainbow color table
ctable = transpose(colortable(13))
;Step through the color table one RGB pair at a time, set the color
;of the polygon, update the window, and save to the video stream.
for i=0, 255 do begin
oPoly.SetProperty, COLOR=ctable[*, i]
win.Refresh
capture = win.CopyWindow()
timestamp = vid.put(stream, capture)
endfor
;Destroy the video object to finish writing.
vid.Cleanup
end
After running this code there will be video of a triangle changing colors in .mp4 format in IDL's current directory.