How to create a contour plot with different styles of line fill

The following code example shows how to set up different styles of line fill in a contour plot using IDL's CONTOUR procedure.


pro contour_different_style_linefill

; Initialize the display settings and load a color table
device,decomposed=0
loadct, 26

; Access the values of the color table and set them up
tvlct,r,g,b,/get
 r[0]=255
 g[0]=255
 b[0]=255
 r[255]=0
 g[255]=0
 b[255]=0
 
; Load these these values to the display
tvlct,r,g,b

; Create a simple, random dataset for contouring
data = randomu(seed, 7, 7)

; Set one color for each contour line
c_colors=[ 100, 120, 80, 40, 200, 0]

; Create a line filled contour plot with 6
; evenly-spaced levels.
contour, data, nlevels=6, c_thick=[2.0,2.0] , $
/cell_fill , $
c_orientation=60,$   ;draw fill lines at a 60 degree angle
c_colors=c_colors, $
c_spacing=0.40 ,$  ;0.4 cm between fill lines
c_linestyle = indgen(6) ; one style for each contour

; Overplot the actual contour lines and label each one
contour, data, nlevels=6, $
/noerase, /overplot ,$
c_labels=[1, 1, 1, 1, 1, 1 ], $ ;one label for each line
c_colors=255, $
c_thick=[2,2]

END