What I love about the IDL language

One thing described in last week's edition of IDL Data Point is not only how easy it can be to perform a task in IDL, but also how IDL provides more than one way to get the task done. 

Although some ways are more efficient than others, there are times when I want to quickly throw code together for a small project. IDL is a great tool if I want to easily process or visualize some data without much effort. Once my code is written, I can tweak it with a few tricks to make it more efficient. This is easy to do because in the IDL workbench, I can recompile the code with a quick click of a button without worrying about using a compiler.

Here is an example that just came to the top of my head. Given an atmospheric sounding (in simple terms, this is data collected from a weather balloon) provided by the University of Wyoming's atmospheric sounding archive, plot the relative humidity vs. height. On this site, select "Text: List" for output and pick a date and click on a location. Copy the raw text data (ignore the header and station information in the bottom) and copy it into a plain text file. 

Now I can use IDL to read and plot this data in 10 lines of code:

  file = dialog_pickfile()
  
  nLines = File_Lines(file)
  openr, unit, file, /GET_LUN
  txtData = StrArr(nLines)
  readf, unit ,txtData
  Free_Lun, unit
  
  data = (StrSplit(txtData, ' ', /EXTRACT)).ToArray()
  height = Long(data[*,1]); Height in meters is the second column
  rh = Long(data[*,4]); Relative humidity (percent) is the 5th column
  p = plot(rh, height, 'r1D-', TITLE='RH vs. Height', XTITLE='RH (%)', YTITLE='Height (m)')

When running the code, a dialog pops up where you select the text file you saved. Now a plot displays. 

With the new graphics interface, I can easily annotate this image with some text and arrows.

Can you imagine doing this in C or any other non-interpreted language? I can't. 

Let's have some more programming fun. I now want to know at what heights is it likely to be cloudy. I will arbitrarily define cloudy as relative humidity being greater than 95% (there are probably more scientific ways of determining whether the air is cloudy, but where RH > 95 provides an example of a very simple algorithm to implement). Here are a few more lines of code that provide the answer:

  result = Where(rh gt 95, count)
  isCloudy = (count gt 0)
  if (isCloudy) then begin
    cloudLayers = height[result]
  endif

  print, isCloudy

  print, cloudLayers

This demonstrates how easy it is to prototype and develop algorithms in IDL. I don't even need to worry about declaring variable types - that sort of thing is IDL's job. But IDL's capabilities extend beyond just the code and user-friendly plot tools. The IDL workbench offers the ability to set breakpoints, create projects, write macros, view class hierarchies, and it has a new JSON editor. These are just a few of the tools available for development. 

Additionally, IDL is the language of the ENVI API, which allows user to add custom extensions to ENVI. This provides the benefit of an easy language to develop customized image processing algorithms. 

As far as efficiency goes, here is a link to one of my favorite references on tips for efficient IDL programming: Tips & Tricks for Efficient IDL Programming