MaskRaster Task

This task applies a mask to a source raster.

The virtual raster associated with this task is ENVIMaskRaster.

Example

; Start the application

e = ENVI()

; Open an input file

File = Filepath('qb_boulder_msi', Subdir=['data'], $

  Root_Dir=e.Root_Dir)

Raster = e.OpenRaster(File)

; Define a spectral subset of one band

Subset = ENVISubsetRaster(Raster, Band=[0])

; Create a raster for masking

threshold = [216.]

rasterBinaryImage = ENVIBinaryGTThresholdRaster(Subset, threshold)

; Get the task from the catalog of ENVITasks

Task = ENVITask('MaskRaster')

; Define inputs

Task.DATA_IGNORE_VALUE = 0

Task.INPUT_MASK_RASTER = rasterBinaryImage

Task.INPUT_RASTER = raster

; Run the task

Task.Execute

; Get the collection of data objects currently available in the Data Manager

DataColl = e.Data

; Add the output to the Data Manager

DataColl.Add, Task.OUTPUT_RASTER

; Display the result

View = e.GetView()

Layer = View.CreateLayer(Task.OUTPUT_RASTER)

Syntax

Result = ENVITask('MaskRaster')

Input parameters (Set, Get): DATA_IGNORE_VALUE, INPUT_MASK_RASTER, INPUT_RASTER, INVERSE, OUTPUT_RASTER_URI

Output parameters (Get only): OUTPUT_RASTER

Parameters marked as "Set" are those that you can set to specific values. You can also retrieve their current values any time. Parameters marked as "Get" are those whose values you can retrieve but not set.

Input Parameters

DATA_IGNORE_VALUE (required)

Specify a unique data value for pixels in the output raster that have a non-zero pixel state value.

INPUT_MASK_RASTER (required)

Specify a single-band mask raster with the same spatial dimensions as the input raster. A pixel value of 0 in the input mask indicates that the pixel location should be masked in the output.

INPUT_RASTER (required)

Specify a raster on which to perform masking.

INVERSE (optional)

Set this parameter to invert the input mask.

OUTPUT_RASTER_URI (optional)

Specify a string with the fully qualified filename and path to export the associated OUTPUT_RASTER.

If you set this parameter to an asterisk symbol (*), the output raster will be virtual and not written to disk.
If you do not specify this parameter, or set it to an exclamation symbol (!), a temporary file will be created.
If you set it to the hash symbol (#), ENVI creates a file in the temporary directory, but this file will not be deleted when ENVI closes.