This task creates a buffer zone image from a classification image. Each pixel in the output image is the nearest distance, in pixels, from any classified pixel specified by CLASS_NAME.

Example

; Start the application
e = ENVI()
 
; Open an input raster and vector
File1 = Filepath('qb_boulder_msi', Subdir=['data'], $
  Root_Dir=e.Root_Dir)
Raster = e.OpenRaster(File1)
File2 = Filepath('qb_boulder_msi_vectors.shp', Subdir=['data'], $
  Root_Dir=e.Root_Dir)
Vector = e.OpenVector(File2)
 
; Get training statistics
StatTask = ENVITask('TrainingClassificationStatistics')
StatTask.INPUT_RASTER = Raster
StatTask.INPUT_VECTOR = Vector
StatTask.Execute
 
; Get the task from the catalog of ENVITasks
ClassTask = ENVITask('SpectralAngleMapperClassification')
 
; Define inputs
ClassTask.INPUT_RASTER = Raster
ClassTask.MEAN = StatTask.MEAN
 
; Run the task
ClassTask.Execute
 
; Get the collection of data objects currently available in the Data Manager
DataColl = e.Data
 
; Add the output to the Data Manager
DataColl.Add, ClassTask.OUTPUT_RASTER
 
; Display the result
View = e.GetView()
Layer = View.CreateLayer(ClassTask.OUTPUT_RASTER)
 
 
; Run the buffer zonetask
BufferZoneTask = ENVITask('BufferZone')
BufferZoneTask.INPUT_RASTER =  ClassTask.OUTPUT_RASTER
BufferZoneTask.CLASS_NAME = 'Class 1'
BufferZoneTask.OUTPUT_DATA_TYPE = 'Float'
BufferZoneTask.MAXIMUM_DISTANCE = 20
BufferZoneTask.Execute
 
; Add the output to the Data Manager
DataColl.Add, BufferZoneTask.OUTPUT_RASTER
 
; Display the result
Layer2 = View.CreateLayer(BufferZoneTask.OUTPUT_RASTER)

Syntax

Result = ENVITask('BufferZone')

Input properties (Set, Get): CLASS_NAME, INPUT_RASTER, MAXIMUM_DISTANCE, OUTPUT_DATA_TYPE, OUTPUT_RASTER_URI

Output properties (Get only): OUTPUT_RASTER

Properties marked as "Set" are those that you can set to specific values. You can also retrieve their current values any time. Properties marked as "Get" are those whose values you can retrieve but not set.

Methods

This task inherits the following methods from ENVITask:

AddParameter

Execute

Parameter

ParameterNames

RemoveParameter

Properties

This task inherits the following properties from ENVITask:

COMMUTE_ON_DOWNSAMPLE

COMMUTE_ON_SUBSET

DESCRIPTION

DISPLAY_NAME

NAME

REVISION

TAGS

This task also contains the following properties:

CLASS_NAME (required)

Specify an array with the names of the classes around which to compute the buffer zone.

INPUT_RASTER (required)

Specify a classification raster.

MAXIMUM_DISTANCE (optional)

Specify a long integer representing the maximum distance (in pixels) for the buffer zone.

The default value is 10000.

OUTPUT_DATA_TYPE (optional)

Specify the output data type.

  • Integer (default)
  • Float

OUTPUT_RASTER

This is a reference to the output raster of filetype ENVI.

OUTPUT_RASTER_URI (optional)

Specify a string with the fully qualified filename and path of the associated OUTPUT_RASTER. If you do not specify this property, or set it to an exclamation symbol (!), a temporary file will be created.

Version History

ENVI 5.5. 1

Introduced

API Version

4.3

See Also

ENVITask, ENVISubsetRaster