MatchedFilter Task

This task performs a matched filter supervised classification. See Matched Filtering for details.

Example

This example performs the following steps:

Opens an AVIRIS hyperspectral image subset.
Runs a forward minimum noise transform (MNF) to reduce noise in the data.
Defines three regions of interest (ROIs), each containing nine pixels of a common material.
Retrieves the spectra from the ROIs and uses their means as endmembers for matched filtering.
Runs the MatchedFilter task.
Displays the result. To see all of the bands, open the Data Manager. ENVI creates three MF Score images (one for each ROI) and three Infeasibility images.

; Start the application

e = ENVI()

; Open an input file

File = Filepath('AVIRISReflectanceSubset.dat', $

  SUBDIR=['data', 'hyperspectral'], $

  ROOT_DIR=e.Root_Dir)

Raster = e.OpenRaster(File)

; First run a Forward MNF on the data

Task = ENVITask('ForwardMNFTransform')

Task.INPUT_RASTER = Raster

Task.Execute

; Use the first 25 MNF bands to run a matched filter

Subset = ENVISubsetRaster(Task.OUTPUT_RASTER, BANDS=LINDGEN(25))

; Define three ROIs, each containing 9 pixels of a common material.

nSpectra = 9d

roi1 = ENVIROI(NAME='Green Field')

pixelAddr1 = [[77,182],[78,182],[79,182], $

  [77,183],[78,183],[79,183], $

  [77,184],[78,184],[79,184]]

roi1.AddPixels, pixelAddr1, SPATIALREF=Subset.SPATIALREF

roi2 = ENVIROI(NAME='Soil')

pixelAddr2 = [[386,285],[387,285],[388,285], $

  [386,286],[387,286],[388,286], $

  [386,287],[387,287],[388,287]]

roi2.AddPixels, pixelAddr2, SPATIALREF=Subset.SPATIALREF

roi3 = ENVIROI(NAME='Ground')

pixelAddr3 = [[296,326],[297,326],[298,326], $

  [296,327],[297,327],[298,327], $

  [296,328],[297,328],[298,328]]

roi3.AddPixels, pixelAddr3, SPATIALREF=Subset.SPATIALREF

; Retrieve the spectra from the ROIs and use their mean as

; endmembers for the Matched Filter task

spectra1 = Subset.GetData(ROI=roi1)

mean1 = Total(spectra1,1) / nSpectra

spectra2 = Subset.Getdata(ROI=roi2)

mean2 = Total(spectra2,1) / nSpectra

spectra3 = Subset.GetData(ROI=roi3)

mean3 = Total(spectra3,1) / nSpectra

endmembers = [[mean1],[mean2],[mean3]]

; Get the task from the catalog of ENVITasks

Task = ENVITask('MatchedFilter')

Task.INPUT_RASTER = Subset

Task.ENDMEMBERS = endmembers

Task.NAMES = ['Green Field', 'Soil', 'Ground']

; Run the task

Task.Execute

; Get the data collection

dataColl = e.Data

; Add the output to the data collection

dataColl.Add, Task.OUTPUT_RASTER

; Display the result

View = e.GetView()

Layer = View.CreateLayer(Task.OUTPUT_RASTER)

Syntax

Result = ENVITask('MatchedFilter')

Input parameters (Set, Get): COVARIANCE, BACKGROUND_THRESHOLD, ENDMEMBERS, INPUT_RASTER, MEAN, NAMES, OUTPUT_RASTER_URI, REGULARIZATION_METHOD, REGULARIZATION_TOLERANCE, USE_SUBSPACE_BACKGROUND

Output parameters (Get only): OUTPUT_RASTER

Parameters marked as "Set" are those that you can set to specific values. You can also retrieve their current values any time. Parameters marked as "Get" are those whose values you can retrieve but not set.

Input Parameters

BACKGROUND_THRESHOLD (optional)

Specify the background threshold to use when calculating statistics using the subspace background. The default value is 0.9.

COVARIANCE (optional)

Specify an array that is the covariance matrix of the input bands. The array size is [number of bands, number of bands].

ENDMEMBERS (required)

Specify an array that is [number of bands, number of classes].

INPUT_RASTER (required)

Specify a raster on which to perform the matched filter classification.

MEAN (optional)

Specify an array that is the mean of the input bands. The number of elements in the array must match the number of bands.

NAMES (optional)

This is an array of endmember names.

OUTPUT_RASTER_URI (optional)

Specify a string with the fully qualified filename and path of the associated OUTPUT_RASTER.

If you do not specify this parameter, or set it to an exclamation symbol (!), ENVI creates a temporary file.
If you set it to the hash symbol (#), ENVI creates a file in the temporary directory, but this file will not be deleted when ENVI closes.

REGULARIZATION_METHOD (optional)

Specify a method for regularizing the covariance matrix:

Diagonal: Diagonal loading, increasing all singular values by the tolerance value.
Dominant: Dominant mode rejection, setting singular values less than the tolerance value to their mean.
None: No regularization is used.
Shrink: Shrinkage of singular values based on the tolerance value.
Threshold: Singular values less than the tolerance value are set to the tolerance value.
Truncate (default): Singular values less than the tolerance value are set to zero.