SpectralAdaptiveCoherenceEstimator Task

This task performs Adaptive Coherence Estimator (ACE) target detection analysis.

To perform ACE using subspace background statistics, see the SpectralAdaptiveCoherenceEstimatorUsingSubspaceBackgroundStatistics task.

Example

ACE target detection involves multiple steps, as this code example demonstrates:

Open a spectral library.
Open a hyperspectral image.
Get the wavelength values and units from the image.
Choose an individual spectrum from the spectral library.
Resample the spectrum to the wavelengths of the image.
Run ACE target detection.
Display the resulting image. Brighter pixels represent a close match to the Dry Grass spectrum.

This example takes several minutes to complete. Copy and paste the following code into the IDL Editor:

; Launch the application

e = ENVI()

; Open a spectral library

specLibFile = FILEPATH('veg_2grn.sli', ROOT_DIR=e.ROOT_DIR, $

  SUBDIR=['resource', 'speclib', 'veg_lib'])

specLib = ENVISpectralLibrary(specLibFile)

; Open a hyperspectral image

file = FILEPATH('AVIRISReflectanceSubset.dat', $

  ROOT_DIR=e.ROOT_DIR, $

  SUBDIRECTORY = ['data', 'hyperspectral'])

raster = e.OpenRaster(file)

; Get wavelength values and units from raster

metadata = raster.METADATA

wavelengths = metadata['Wavelength']

wavelengthUnits = metadata['Wavelength Units']

; Get the selected spectrum from spectral library

Task1 = ENVITask('GetSpectrumFromLibrary')

Task1.INPUT_SPECTRAL_LIBRARY = specLib

Task1.SPECTRUM_NAME = 'Dry Grass'

Task1.Execute

; Get the resample spectrum task from the catalog of ENVITasks

Task2 = ENVITask('ResampleSpectrum')

; Define inputs

; Spectrum from library to be resampled

Task2.INPUT_SPECTRUM = Task1.SPECTRUM

; Wavelengths from spectral library

Task2.INPUT_WAVELENGTHS = Task1.WAVELENGTHS

; Wavelength units from spectral library

Task2.INPUT_WAVELENGTH_UNITS = Task1.WAVELENGTH_UNITS

; Wavelengths from raster

Task2.RESAMPLE_WAVELENGTHS = wavelengths

; Wavelength units from raster

Task2.RESAMPLE_WAVELENGTH_UNITS = wavelengthUnits

; Run the resample spectrum task

Task2.Execute

; Get the ACE task from the catalog of ENVITasks

ACETask = ENVITask('SpectralAdaptiveCoherenceEstimator')

; Define inputs

ACETask.INPUT_RASTER = raster

ACETask.SPECTRA = Task2.OUTPUT_SPECTRUM

; Run the task

ACETask.Execute

; Get the collection of data objects currently available in the Data Manager

DataColl = e.Data

; Add the output to the Data Manager

DataColl.Add, ACETask.OUTPUT_RASTER

; Display the result

View = e.GetView()

Layer = View.CreateLayer(ACETask.OUTPUT_RASTER)

Syntax

Result = ENVITask('SpectralAdaptiveCoherenceEstimator')

Input properties (Set, Get): COVARIANCE, INPUT_RASTER, MEAN, OUTPUT_RASTER_URI, SPECTRA

Output properties (Get only): OUTPUT_RASTER

Properties marked as "Set" are those that you can set to specific values. You can also retrieve their current values any time. Properties marked as "Get" are those whose values you can retrieve but not set.

Methods

This task inherits the following methods from ENVITask:

Properties

This task inherits the following properties from ENVITask:

COMMUTE_ON_DOWNSAMPLE

COVARIANCE (optional)

Specify an array that is the covariance matrix of the input bands. The array size is [number of bands, number of bands].

INPUT_RASTER (required)

Specify a raster on which to perform the Adaptive Coherence Estimator.

MEAN (optional)

Specify an array that is the mean of the input bands. The number of elements in the array must match the number of bands.

OUTPUT_RASTER

This is a reference to the output raster of filetype ENVI.

OUTPUT_RASTER_URI (optional)

Specify a string with the fully qualified filename and path of the associated OUTPUT_RASTER. If you do not specify this property, or set it to an exclamation symbol (!), a temporary file will be created.

SPECTRA (required)

Specify a floating-point array with the target spectra. The array size is [number of bands, number of target spectra].

Version History

ENVI 5.2. 1

Introduced

API Version

4.3