ENVIConfusionMatrix::Accuracy

The Accuracy function method returns the overall accuracy of a confusion matrix.

The overall accuracy is calculated by summing the number of correctly classified values and dividing by the total number of values. The correctly classified values are located along the upper-left to lower-right diagonal of the confusion matrix. The total number of values is the number of values in either the truth or predicted-value arrays.

In the example confusion matrix, the overall accuracy is computed as follows:

Correctly classified values: 2385 + 332 + 908 + 1084 + 2053 = 6762

Total number of values: 6808

Overall accuracy: 6762 / 6808 = 0.993243

Example

The code example below evaluates classifications using a confusion matrix.

PRO EvaluateClassificationUsingConfusionMatrix

    COMPILE_OPT IDL2

    ; Start the application

    e = ENVI()

    ; Open an input file

    File = Filepath('qb_boulder_msi', Subdir=['data'], $

    Root_Dir=e.Root_Dir)

    Raster = e.OpenRaster(File)

    File2 = Filepath('qb_boulder_roi.xml', Subdir=['data'], $

    Root_Dir=e.Root_Dir)

    Rois = envi.OpenROI(roiFile)

    ; Get training statistics

    StatTask = ENVITask('ROIStatistics')

    StatTask.INPUT_RASTER = Raster

    StatTask.INPUT_ROI = Rois

    StatTask.Execute

    ; Get the task from the catalog of ENVITasks

    Task = ENVITask('MahalanobisDistanceClassification')

    ; Define inputs

    Task.INPUT_RASTER = Raster

    Task.COVARIANCE = StatTask.Covariance

    Task.MEAN = StatTask.Mean

    Task.CLASS_PIXEL_COUNT = StatTask.Roi_Pixel_Count

    Task.CLASS_NAMES = [Rois[0].name, Rois[1].name, Rois[2].name]

    Task.CLASS_COLORS = [[0,0,255], [0,255,0], [255,0,0]]

    ; Run the task and display the result

    Task.Execute

    ClassRaster = Task.OUTPUT_RASTER

    View = e.GetView()

    Layer = View.CreateLayer(ClassRaster)

    ; Add the output to the Data Manager

    envi.Data.Add, ClassRaster

    ; Calculate the confusion matrix

    ConfusionMatrix = ENVICalculateConfusionMatrixFromRaster(ClassRaster, Rois)

    ; Print results

    Print, 'Confusion Matrix:'

    Print, ConfusionMatrix.Confusion_Matrix

    Print, 'Errors of commission: '

    Print, Transpose([[ConfusionMatrix.Column_Names+': '], [(ConfusionMatrix.CommissionError()).ToString()]])

    Print, 'Errors of omission: '

    Print, Transpose([[ConfusionMatrix.Column_Names+': '], [(ConfusionMatrix.OmissionError()).ToString()]])

    Print, 'Overall accuracy: ', ConfusionMatrix.Accuracy()

END

Syntax

Result = ENVIConfusionMatrix.Accuracy([, ERROR=variable])

Return Value

This function method returns the overall accuracy from a confusion matrix.

Arguments

None

Keywords

ERROR (optional)

Set this keyword to a named variable that will contain any error message issued during execution of this routine. If no error occurs, the ERROR variable will be set to a null string (''). If an error occurs and the routine is a function, then the function result will be undefined.

When this keyword is not set and an error occurs, ENVI returns to the caller and execution halts. In this case, the error message is contained within !ERROR_STATE and can be caught using IDL's CATCH routine. See IDL Help for more information on !ERROR_STATE and CATCH.

See Manage Errors for more information on error handling in ENVI programming.

Version History

ENVI 5.4

Introduced

API Version

4.3