BuildRasterSeries Task

This task builds an ENVI raster series file for spatiotemporal analysis.

Example

This example builds a raster series file from sample NCEP Reanalysis-II data included with your installation of ENVI. See More Examples for other code examples.

; Start the application

e = ENVI()

TimeSeriesDir = Filepath('', Subdir=['data','time_series'], $

  Root_Dir = e.Root_Dir)

files = File_Search(TimeSeriesDir, 'AirTemp*.dat')

numRasters = N_Elements(files)

rasters = ObjArr(numRasters)

FOR i=0, (numRasters-1) DO $

  rasters[i] = e.OpenRaster(files[i])

; Get the task from the catalog of ENVITasks

Task = ENVITask('BuildRasterSeries')

; Define inputs

Task.INPUT_RASTERS = rasters

; Run the task

Task.Execute

; Print the contents of the series file

SeriesFile = Task.OUTPUT_RASTERSERIES

SeriesFile

IDL prints:

Description: Raster Series 2014-04-10T16-45-53Z

Data Type: 5

Version: 5.1.1

Total Number of files: 12

Regular Grid: true

0:    2012-12-29T00:00:00Z:    ...\AirTemp_2012122900.dat

1:    2012-12-29T06:00:00Z:    ...\AirTemp_2012122906.dat

2:    2012-12-29T12:00:00Z:    ...\AirTemp_2012122912.dat

3:    2012-12-29T18:00:00Z:    ...\AirTemp_2012122918.dat

4:    2012-12-30T00:00:00Z:    ...\AirTemp_2012123000.dat

5:    2012-12-30T06:00:00Z:    ...\AirTemp_2012123006.dat

6:    2012-12-30T12:00:00Z:    ...\AirTemp_2012123012.dat

7:    2012-12-30T18:00:00Z:    ...\AirTemp_2012123018.dat

8:    2012-12-31T00:00:00Z:    ...\AirTemp_2012123100.dat

9:    2012-12-31T06:00:00Z:    ...\AirTemp_2012123106.dat

10:   2012-12-31T12:00:00Z:    ...\AirTemp_2012123112.dat

11:   2012-12-31T18:00:00Z:    ...\AirTemp_2012123118.dat

Syntax

Result = ENVITask('BuildRasterSeries')

Input parameters (Set, Get): INPUT_RASTERS, OUTPUT_RASTERSERIES_URI

Output parameters (Get only): OUTPUT_RASTERSERIES

Parameters marked as "Set" are those that you can set to specific values. You can also retrieve their current values any time. Parameters marked as "Get" are those whose values you can retrieve but not set.

Input Parameters

INPUT_RASTERS (required)

Specify an array of rasters from which to build the ENVI raster series.

OUTPUT_RASTERSERIES_URI (optional)

Specify a string with the fully-qualified path and filename for OUTPUT_RASTERSERIES.

Output Parameters

OUTPUT_RASTERSERIES

This is a reference to the output raster series file (.series) in JSON format.

Methods

Execute

Parameter

ParameterNames

Properties

More Examples

Build a Raster Series from Multi-Segment NITF Data

This code sample shows how to open NITF files with multiple image segments, then build a raster series from those image segments. This is a hypothetical example; it does not use a specific file for illustration:

Task = ENVITask('BuildRasterSeries')

File1 = 'MultiFile1.ntf'

Raster1 = e.OpenRaster(File1)

File2 = 'MultiFile2.ntf'

Raster2 = e.OpenRaster(File2)

Task.INPUT_RASTERS = [Raster1, Raster2]

Task.OUPUT_RASTERSERIES_URI = e.GetTemporaryFilename('series')

Task.Execute

Build a Raster Series from HDF5 Data

This code sample shows how to to open specific datasets within an HDF5 file, then build a raster series from those image segments. This is a hypothetical example; it does not use a specific file for illustration.

Tip: You can use the IDL H5_LIST routine to get a list of dataset names in an HDF5 file.

Task = ENVITask('BuildRasterSeries')

File = 'C:\Data\ProbaV\S1TOAFile.h5'

Raster1 = e.OpenRaster(File, DATASET_NAME='/LEVEL3/RADIOMETRY/BLUE/TOA')

Raster2 = e.OpenRaster(File, DATASET_NAME='/LEVEL3/RADIOMETRY/NIR/TOA')

Raster3 = e.OpenRaster(File, DATASET_NAME='/LEVEL3/RADIOMETRY/RED/TOA')

Raster4 = e.OpenRaster(File, DATASET_NAME='/LEVEL3/RADIOMETRY/SWIR/TOA')

Task.INPUT_RASTERS = [Raster1, Raster2, Raster3, Raster4]

Task.OUTPUT_RASTERSERIES_URI = e.GetTemporaryFilename('series')

Task.Execute

Version History

ENVI 5.2	Introduced
ENVI 5.5	Replaced INPUT_RASTER_URI with INPUT_RASTERS