ENVIAnnotationLayer::MoveToBottom

The MoveToBottom method moves the ENVIAnnotationLayer to the bottom of the order stack.

Example

; Start the application

e = ENVI()

; Open an input file

file = FILEPATH('qb_boulder_msi', $

  ROOT_DIR=e.ROOT_DIR, SUBDIRECTORY = ['data'])

raster = e.OpenRaster(file)

; Display the raster layer

View = e.GetView()

RasterLayer = View.CreateLayer(raster)

; Create an annotation set using Geographic Lat/Lon

; WGS-84 as the spatial reference

annotation = ENVIAnnotationSet(/GEOGRAPHIC)

; Label the community park

annotation.AddCircle, $

-105.22101050, 39.9917, $ ; X and Y coordinates

  [300.0, 200.0], $ ; ellipse axes (m)

  LINE_COLOR='lime green', NAME='Park polygon'

annotation.AddText, $

  -105.22118409, 39.99424191, $ ; X and Y coordinates

  'East Boulder!C Community Park', $

  GLYPH_COLOR='lime green', NAME='Park label'

; Save the annotation set

outFile = e.GetTemporaryFilename()

annotation.Save, outFile

; Display the annotation layer

AnnLayer = View.CreateLayer(annotation)

; Create another annotation set

annotation2 = ENVIAnnotationSet(/GEOGRAPHIC)

; Label the reservoir

annotation2.AddText, $

  -105.20407487D, 39.99911740D, $ ; X and Y coordinates

  'Baseline!C Reservoir', $

  GLYPH_COLOR='light sky blue', NAME='Reservoir label'

; Save the annotation set

outFile2 = e.GetTemporaryFilename()

annotation2.Save, outFile2

; Display the second annotation layer

AnnLayer2 = View.CreateLayer(annotation2)

; Move the first annotation layer to the bottom

AnnLayer.MoveToBottom

Syntax

ENVIAnnotationLayer.MoveToBottom [, ERROR=variable]

Keywords

ERROR

Set this keyword to a named variable that will contain any error message issued during execution of this routine. If no error occurs, the ERROR variable will be set to a null string (''). If an error occurs and the routine is a function, then the function result will be undefined.

When this keyword is not set and an error occurs, ENVI returns to the caller and execution halts. In this case, the error message is contained within !ERROR_STATE and can be caught using IDL's CATCH routine. See IDL Help for more information on !ERROR_STATE and CATCH.

See Manage Errors for more information on error handling in ENVI programming.

Version History

ENVI 5.6.1

Introduced

API Version

4.2