Examples

---

In the following example, we draw a surface data set with the iSurface iTool, and rotate the image around the x axis.

; Read the data from surface.dat        

file = FILEPATH('surface.dat', $        

   SUBDIRECTORY = ['examples', 'data'])        

data = READ_BINARY(file, DATA_DIMS = [350, 450], DATA_TYPE = 2, $        

   ENDIAN = 'little')        

; Plot the data        

ISURFACE, data, TITLE = 'Maroon Bells Elevation', $        

   COLOR = [255, 128, 0]        

; Insert a dialog box to pause the flow of action        

result = DIALOG_MESSAGE('Click OK to rotate.', /INFORMATION)        

; Rotate the image 45 degrees around the x-axis        

IROTATE, 'surface', 45, /XAXIS            

Syntax

---

IROTATE, Id, Degrees, [, /RESET] [, TOOL=iToolID] [, /XAXIS] [, /YAXIS] [, /ZAXIS]

Arguments

---

Id

The identifier of the object to rotate. If you pass a partial identifier, the IGETID function is called to retrieve the full identifier string.

Degrees

The number of degrees to rotate the object. Positive values represent clockwise rotation as if looking along the positive axis. Degrees is required unless RESET is set.

Keywords

---

RESET

Set this keyword to reset the current rotation before applying any inputs.

TOOL

Set this keyword to the identifer of the iTool in which ID is found. If not supplied, the current iTool is used.

XAXIS

Set this keyword to rotate the object around the X axis.

YAXIS

Set this keyword to rotate the object around the Y axis.

ZAXIS

Set this keyword to rotate the object around the Z axis (the default behavior).

Version History

---

7.1	Introduced

See Also

---

IGETID, ISCALE, ITRANSLATE, IZOOM