AutoChangeThresholdClassification Task

This task uses pre-defined thresholding techniques to automatically classify change detection between two images.

Example

This example performs a difference analysis between two images from different dates, then it performs automatic thresholding for change detection. The images represent NCEP-Reanalysis 2 air temperatures (K) at the 1000-isobar level, at 0600 hours Zulu time. The first image is from 29 December 2012, and the second is from 31 December 2012. Each image has one band. This example uses sample data from the ENVI installation path.

; Start the application

e = ENVI()

TimeSeriesDir = Filepath('', Subdir=['data','time_series'], $

  Root_Dir = e.Root_Dir)

files = File_Search(TimeSeriesDir, 'AirTemp*.dat')

numRasters = N_Elements(files)

rasters = ObjArr(numRasters)

FOR i=0, (numRasters-1) DO $

  rasters[i] = e.OpenRaster(files[i])

; Get the task from the catalog of ENVITasks

Task = ENVITask('BuildTimeSeries')

; Define inputs

Task.INPUT_RASTERS = rasters

; Run the task

Task.Execute

; Get the raster that corresponds to 0600,

; 29 December 2012 (index #1).

; Indices are zero-based.

SeriesFile = Task.OUTPUT_RASTERSERIES

SeriesFile.Set, 0

Image1 = SeriesFile.Raster

; Get the raster that corresponds to 0600,

; 31 December 2012 (index #9).

; Indices are zero-based.

SeriesFile.Set, 8

Image2 = SeriesFile.Raster

; Get the task from the catalog of ENVITasks

Task = ENVITask('ImageBandDifference')

; Define inputs

Task.INPUT_RASTER1 = Image1

Task.INPUT_RASTER2 = Image2

; Run the task

Task.Execute

; Get the task from the catalog of ENVITasks

AutoChangeThreshTask = ENVITask('AutoChangeThresholdClassification')

; Define inputs

AutoChangeThreshTask.INPUT_RASTER = Task.OUTPUT_RASTER

; Run the task

AutoChangeThreshTask.Execute

; Get the collection of data objects currently available in the Data Manager

DataColl = e.Data

; Add the output to the Data Manager

DataColl.Add, AutoChangeThreshTask.OUTPUT_RASTER

; Display the result

View = e.GetView()

Layer = View.CreateLayer(AutoChangeThreshTask.OUTPUT_RASTER)

Syntax

Result = ENVITask('AutoChangeThresholdClassification')

Input parameters (Set, Get): CHANGE_TYPE, INPUT_RASTER, OUTPUT_RASTER_URI, THRESHOLD_METHOD

Output parameters (Get only): OUTPUT_RASTER

Parameters marked as "Set" are those that you can set to specific values. You can also retrieve their current values any time. Parameters marked as "Get" are those whose values you can retrieve but not set.

Input Parameters

CHANGE_TYPE (optional)

Specify the change of interest:

Both (default): Shows areas of increase (in blue) and decrease (in red).
Increase: Shows areas of increase (in blue) only.
Decrease: Shows areas of decrease (in red) only.

INPUT_RASTER (required)

Specify a raster on which to threshold.

OUTPUT_RASTER_URI (optional)

Specify a string with the fully qualified filename and path of the associated OUTPUT_RASTER.

If you do not specify this parameter, or set it to an exclamation symbol (!), ENVI creates a temporary file.
If you set it to the hash symbol (#), ENVI creates a file in the temporary directory, but this file will not be deleted when ENVI closes.

THRESHOLD_METHOD (optional)

Specify the thresholding method.

Otsu (default): A histogram shape-based method that is based on discriminate analysis. It uses the zero- and first-order cumulative moments of the histogram for calculating the value of the thresholding level.
Tsai: A moment-based method. It determines the threshold so that the first three moments of the input image are preserved in the output image.
Kapur: An entropy-based method. It considers the thresholding image as two classes of events, with each class characterized by a Probability Density Function (PDF). The method then maximizes the sum of the entropy of the two PDFs to converge on a single threshold value.
Kittler: A histogram shape-based method. It approximates the histogram as a bimodal Gaussian distribution and finds a cutoff point. The cost function is based on the Bayes classification rule.