ISETPROPERTY

Note: The keyword name used to set the property may not be the same as the human-readable name displayed on the property sheet. You can call IGETPROPERTY with the _REGISTERED keyword to retrieve all of a visualization’s registered properties.

Note: If you misspell a property keyword or try to set a property keyword that does not exist for a particular iTool, no error will be generated.

Examples

In the following example, we plot a simple sine wave with iPlot. After retrieving the list of properties for an iPlot object, as well as the value of the current plotting line style, we set new visualization properties for the plot.

; Plot a sine wave

X = 2*!PI/35 * FINDGEN(35)

IPLOT, SIN(X)

; Retrieve all iPlot tool properties

IGETPROPERTY, 'plot', _REGISTERED=plotProperties

PRINT, 'The iPlot properties are: ', plotProperties

; What is the current plotting line style?

IGETPROPERTY, 'plot', LINESTYLE = plotLineStyle

PRINT, 'The current line style = ', plotLineStyle

; Insert a dialog box to pause the flow of action

result = DIALOG_MESSAGE('Click OK to set the plot properties.', $

   /INFORMATION)

; Change the solid line to individual plot points,

; with each point represented as a red square

ISETPROPERTY, 'plot', LINESTYLE = 6, SYM_INDEX = 6, $

   SYM_COLOR = [255, 0, 0]

Syntax

ISETPROPERTY, Id [, PROPERTY=value] [, TOOL=value]

Arguments

Id

A string containing the identifier of the iTools object on which to set the property. If you pass a partial identifier, the IGETID function is called to retrieve the full identifier string.

Keywords

To set the value of a property, specify the property name as a keyword set equal to the value. If you set multiple properties at once, they are set internally in alphabetical order.

All other keywords are passed to the iTools object.

TOOL

Set this keyword to a string specifying one or more iTools in which to search for Id. If this keyword is not set, only the current iTool is searched.

Version History

7.1	Introduced

Product	IDL

Version	9.0