STREAMLINE

The STREAMLINE function draws a streamline plot.

Example

The following lines create the graphic shown at the top of this topic.

n = 101

x = 10*DINDGEN(n)/(n-1) - 5

y = 10*DINDGEN(n)/(n-1) - 5

xx = REBIN(x, n, n)

yy = REBIN(TRANSPOSE(y), n, n)

mu = 1

xdot = mu*(xx - xx^3/3 - yy)

ydot = xx/mu

s = STREAMLINE(xdot, ydot, x, y, $

 ARROW_COLOR="Dodger blue", $

 ARROW_OFFSET=[0.25,0.5,0.75,1], $

 STREAMLINE_STEPSIZE=0.05, $

 POSITION=[0.1,0.22,0.95,0.9], $

 X_STREAMPARTICLES=11, Y_STREAMPARTICLES=11, $

 XTITLE='X', YTITLE='Y', $

 TITLE='Van der Pol Oscillator - Phase Portrait')

; Change some properties.

s.THICK = 2

s.AUTO_COLOR = 1

s.AUTO_RANGE = [0.03,0.07]

s.RGB_TABLE = 33

; Add a colorbar.

c = COLORBAR(TARGET=s, MINOR=0, $

 POSITION=[0.35,0.1,0.7,0.125], $

 TITLE='Distance moved per step')

Additional Examples

See Streamline examples for additional examples using the STREAMLINE function.

Syntax

graphic = STREAMLINE(U, V, [, X, Y ] [, Keywords=value] [, Properties=value])

Keywords

Keywords are applied only during the initial creation of the graphic.

AXIS_STYLE=value

/BUFFER, /CURRENT, /DEVICE, DIMENSIONS=[width, height], LAYOUT=array, LOCATION=[x, y], MARGIN=scalar or [left, bottom, right, top], /NO_TOOLBAR, /NODATA, /OVERPLOT, /WIDGETS

Properties

Properties can be set as keywords to the function during creation, or retrieved or changed using the "." notation after creation.

ANTIALIAS, ARROW_COLOR, ARROW_OFFSET, ARROW_SIZE, ARROW_THICK, ARROW_TRANSPARENCY, ASPECT_RATIO, AUTO_COLOR, AUTO_RANGE, AXES, BACKGROUND_COLOR, BACKGROUND_TRANSPARENCY, CLIP, COLOR, CROSSHAIR, DIRECTION_CONVENTION, FONT_COLOR, FONT_NAME, FONT_SIZE, FONT_STYLE, GRID_UNITS, HIDE, NAME, POSITION, RGB_TABLE, STREAMLINE_NSTEPS, STREAMLINE_STEPSIZE, THICK, TITLE, TRANSPARENCY, UVALUE, WINDOW, WINDOW_TITLE, X_STREAMPARTICLES, Y_STREAMPARTICLES, XRANGE, YRANGE, ZVALUE

Methods

Return Value

The STREAMLINE function returns a reference to the created graphic. Use the returned reference to manipulate the graphic after creation by changing properties or calling methods.

Arguments

U

A one or two-dimensional array containing the horizontal components of the vector data. If the X and Y arguments are provided, the streamline starting locations are plotted as a function of the (x, y) locations. Otherwise, the streamline starting locations are plotted as a function of the array index of each element of U.

V

A one or two-dimensional array containing the vertical components of the vector data. V must have the same dimensions as U.

X

A one-dimensional array specifying the x-coordinates for the vector data. If U is a two-dimensional array then X must have the same number of elements as the first dimension of U, where each element of X specifies the x-coordinate for a column of U. If U is a one-dimensional array then X must have the same number of elements as U, where each element of X specifies the x-coordinate for the corresponding element of U.

Y

A one-dimensional array specifying the y-coordinates for the vector data. If U is a two-dimensional array then Y must have the same number of elements as the second dimension of U, where each element of Y specifies the y-coordinate for a row of U. If U is a one-dimensional array then Y must have the same number of elements as U, where each element of Y specifies the y-coordinate for the corresponding element of U.

Keywords

Keywords are applied only during the initial creation of the graphic.

AXIS_STYLE

Set this keyword to one of the following values:

0 - No axes. Decrease the margins so the graphic almost fills the window. This is the default for images.
1 - Single X, Y (and Z if 3D) axes located at the minimum data value. The margins will be adjusted to leave space for the axes. This is the default for 3D graphics.
2 - Box axes - multiple axes located at both the minimum and maximum data values. The margins will be adjusted to leave space for the axes. This is the default for 2D graphics.
3 - Crosshair-style axes - located at the midpoint of each data dimension. Since the axes are in the middle, decrease the margins so the graphic almost fills the window. This is the default for polar plots.
4 - No axes, but use the same margins as if axes were there. This is useful if you want to later add another graphic that does have axes, and you want the two visualizations to be aligned properly.

You can set the following properties on the axes:

Property	Description
[XYZ]COLOR	A string or RGB vector containing the axis color.
[XYZ]GRIDSTYLE	A string, integer, or 2-element vector giving the linestyle for tickmarks.
[XYZ]LOG	Set to 1 if the axis is logarithmic. The minimum value of the axis range must be greater than zero.
[XYZ]MAJOR	The number of major tick marks. Set to -1 to auto-compute, set to 0 to suppress.
[XYZ]MINOR	The number of minor tick marks. Set to -1 to auto-compute, set to 0 to suppress.
[XYZ]SUBGRIDSTYLE	A string, integer, or 2-element vector giving the linestyle for the minor tickmarks. The default is 0, for solid lines. Set to -1 to force minor ticks to have the same linestyle as major ticks.
[XYZ]SHOWTEXT	Set to 1 to show text labels or 0 to hide the text labels.
[XYZ]STYLE	The axis range style. The valid values are: (0) Nice range. Default for all graphics except Image, Barplot, and Map. (1) Force the exact data range. Default for Image, Barplot, and Map. (2) Pad the axes slightly beyond the nice range. (3) Pad the axes slightly beyond the exact data range. The [XYZ]RANGE takes precedence over this property.
[XYZ]SUBTICKLEN	The ratio of the minor tick length to the major tick length. The default is 0.5.
[XYZ]TEXT_COLOR	A string or RGB vector containing the axis text color.
[XYZ]TEXT_ORIENTATION	The angle (in degrees) of the tick mark labels.
[XYZ]TEXTPOS	Set to 1 to position text above the axis. The default is 0, below the axis.
[XYZ]THICK	Set to a floating-point value between 0 and 10 to specify the line thickness for tickmarks. A thickness of 0 gives a thin hairline. The default is 1.
[XYZ]TICKDIR	Set to 1 to draw the tickmarks facing outwards. The default is 0, facing inwards.
[XYZ]TICKFONT_NAME	A string containing the font name for the axis text.
[XYZ]TICKFONT_SIZE	The axis text size in points.
[XYZ]TICKFONT_STYLE	A string or integer containing the font style: normal (0), bold (1), italic (2), or bold italic (3).
[XYZ]TICKFORMAT	A string or string array of tick label formats. See Format Codes for more information.
[XYZ]TICKINTERVAL	The interval between major tick marks.
[XYZ]TICKLAYOUT	Set to 1 to suppress tick marks; set to 2 to draw a box around the tick labels.
[XYZ]TICKLEN	The length of each major tick mark, normalized to the width or height of the graphic. The default value is automatically calculated based upon the aspect ratio of the graphic.
[XYZ]TICKNAME	A string array containing the tick labels.
[XYZ]TICKUNITS	A string giving the tick units. Valid values are: null (the default, signified by empty quotes), Years, Months, Days, Hours, Minutes, Seconds, Time, exponent for exponential notation, or scientific for scientific notation. If any of the time units are utilized, then the tick values are interpreted as Julian date/time values. If more than one unit is provided, the axis will be drawn with multiple levels.
[XYZ]TICKVALUES	An array of tick mark locations.
[XYZ]TITLE	A string giving the axis title.
[XYZ]TRANSPARENCY	An integer from 0-100 giving the percent transparency.

For more detailed explanations of these properties, see the AXIS function.

Tip: You can also use the AXIS function to insert additional axes after the graphic has been created.

BUFFER

Set this keyword to 1 to direct the graphics to an off-screen buffer instead of creating a window.

CURRENT

Set this keyword to create the graphic in the current window with a new set of axes. If no window exists, a new window is created. The WINDOW's SetCurrent method may be used to set the current window.

Or, set this keyword to an existing IDL Graphic reference to make that window be the current window and direct the new graphic to that window.

Tip: The CURRENT keyword is usually used with the LAYOUT keyword or POSITION property to produce a window which has multiple graphics in different locations.

Tip: For the graphic share the same axes as an existing graphic, use the OVERPLOT keyword instead.

DEVICE

Set this keyword if values are specified in device coordinates (pixels) for the MARGIN and POSITION keywords. (Normalized coordinates are the default for these keywords.)

DIMENSIONS

Set this keyword to a two-element vector of the form [width, height] to specify the window dimensions in pixels. If you do not specify a value for DIMENSIONS, IDL by default uses the values of the IDL_GR_WIN_HEIGHT and IDL_GR_WIN_WIDTH preferences for Windows platforms or the IDL_GR_X_HEIGHT and IDL_GR_X_WIDTH preferences for X Windows systems on UNIX.

Tip: The minimum width is set by the toolbar in the window, usually around 400 pixels. To create a smaller graphics window, use the NO_TOOLBAR keyword.

LAYOUT

Set this keyword to a three-element vector [ncol, nrow, index] that arranges graphics in a grid. The first dimension ncol is the number of columns in the grid, nrow is the number of rows, and index is the grid position at which to place the graphic (starting at element 1). This keyword is ignored if either OVERPLOT or POSITION is specified.

LOCATION

Set this keyword to a two-element vector [X offset, Y offset] giving the window's screen offset in pixels.

MARGIN

Set this keyword to the current graphic’s margin values in the layout specified by the LAYOUT property. Use a scalar value to set the same margin on all sides, or use a four-element vector [left, bottom, right, top] to specify different margins on each side.

By default, margin values are expressed in normalized units ranging from 0.0 to 0.5. If the DEVICE keyword is set, the values are given in device units (pixels).

This keyword is ignored if either OVERPLOT or POSITION is specified.

NO_TOOLBAR

By default the graphics window will have a toolbar containing some common tools such as Print and Save. Set this keyword to remove the toolbar. This keyword has no effect if the window is already created.

Tip: When the toolbar exists, the minimum window width is set to the toolbar's width, usually around 400 pixels. To create a smaller graphics window, use the NO_TOOLBAR keyword.

NODATA

Set this keyword to 1 to create the graphic, but without any data attached to it. The axes and title (if present) are also created and displayed. If the OVERPLOT keyword is specified, axis ranges will not change.

Note: You must still provide valid input arguments. The data range of the input arguments are used to automatically set the range of the axes. The [XYZ]RANGE properties may be used to override these default ranges.

OVERPLOT

Set this keyword to 1 (one) to place the graphic on top of the currently-selected graphic within the current window. The two graphics items will then share the same set of axes. If no current window exists, then this keyword is ignored and a new window is created.

If you have a graphic in another window that is not currently selected, you can also set this keyword to that graphic's reference to overplot on top of that graphic.

Tip: For the graphic to have a new set of axes, use the CURRENT keyword instead.

WIDGETS

By default, when running from the IDL Workbench, the graphics window will use the native widgets for your platform. Set this keyword to instead use IDL widgets for the graphics window. This keyword is ignored when running from the IDL command line, since IDL widgets are always used in that case.

Properties

Properties marked as (Init) are applied only during the initial creation of the graphic. All other properties can be set during creation, or retrieved or changed after creation.

ANTIALIAS

By default anti-aliasing is used when drawing lines. Set this property to 0 to disable anti-aliasing.

ARROW_COLOR

Set this property to a string or RGB vector that specifies the color of the arrow heads on the streamlines. The default is the same color as the streamlines.

ARROW_OFFSET

Set this property to a scalar or an array of floating-point values between 0.0 and 1.0, giving the locations of the arrow heads along each streamline. The default is 0.5, which draws an arrow head halfway along each streamline.

ARROW_SIZE

Set this property to a floating-point value giving the normalized size of the arrow heads. The default is 1.0.

ARROW_THICK

Set this property to a value between 1.0 and 10.0, specifying the thickness of the arrow heads. The default is 1.0 points.

ARROW_TRANSPARENCY

Set this property to an integer between 0 and 100 that specifies the percent transparency of the arrow heads. The default value is 0.

ASPECT_RATIO

A floating point value indicating the ratio of the Y dimension to the X dimension in data units. If this property is set to a nonzero value, the aspect ratio will be preserved as the graphic is stretched or shrunk. The default value is 0 for all graphics except images, meaning that the aspect ratio is not fixed, but is allowed to change as the graphic is stretched or shrunk.

AUTO_COLOR

Set this property to enable or disable automatic coloring of streamlines. Possible values are:

0 - No automatic colors (this is the default).
1 - Color according to the distance moved by the particle at each point along the streamline, using the RGB_TABLE.
2 - Color according to the direction in which the particle moved at each point along the streamline, using the RGB_TABLE.

Tip: The AUTO_RANGE property may be used to control the scaling from the data range into the 0-255 color table range.

AUTO_RANGE

Set this property to a two-element vector [min, max] giving the data scaling range for coloring by distance or direction. If AUTO_COLOR=1 or 2, then the distance or direction array is scaled from its original data range into the range 0-255. The AUTO_RANGE property may be used to control the minimum and maximum data values used in this scaling. The default value for AUTO_RANGE is the minimum and maximum values of the distance or direction array.

AXES (Get Only)

This property retrieves an array that contains all of the AXIS objects within the visualization. For example, for a plot visualization:

p = PLOT(/TEST)

 ax = p.AXES

ax[0].TITLE = 'X axis'

ax[1].TITLE = 'Y axis'

ax[2].HIDE = 1  ; hide top X axis

ax[3].HIDE = 1  ; hide right Y axis

See AXIS for a list of the available properties.

BACKGROUND_COLOR

Set this property to a string or RGB vector indicating the graphic's background color. The default value is [255, 255, 255] (white). Set this property to a scalar value to remove the background color.

Tip: To set the background color of the entire window, retrieve the window object using the WINDOW property, and set the BACKGROUND_COLOR on the window object.

BACKGROUND_TRANSPARENCY

Set this property to an integer between 0 and 100 giving the percent transparency of the background color. The default is 100 (completely transparent).

Note: If the BACKGROUND_COLOR property is changed, and the current background transparency is 100, then the BACKGROUND_TRANSPARENCY will be automatically set to 0 (opaque) so that you can see the new color.

CLIP

Set this property to 1 to clip portions of the graphic that lie outside of the dataspace range, or to 0 to disable clipping. The default is 1.

COLOR

Set this property to a string or RGB vector that specifies the streamline color. The default is "black".

CROSSHAIR (Get Only)

Use this property to retrieve a reference to the Crosshair graphic. All graphics objects within the same set of axes share a single Crosshair graphic. For Plot graphics the default behavior is to display the crosshair when a Mouse_Down event is received. For other graphics the crosshair is disabled. The STYLE property may be used to automatically draw the crosshair, while the LOCATION property may be used to manually draw the crosshair.

You can get and set the following properties on the retrieved crosshair:

Property	Description
ANTIALIAS	Set to 1 to enable anti-aliasing for the lines.
COLOR	A string or RGB vector containing the color.
HIDE	Set to 1 to hide the crosshair, 0 to show.
INTERPOLATE	Set to 1 to force interpolation between Plot data points when SNAP is active. For other graphics this property is ignored. The default is 0.
LINESTYLE	An integer or string giving the line style. The default is 'dot'. See Linestyle Values for additional options.
LOCATION	The location at which to draw the crosshair. For Plot graphics, if SNAP is enabled, then only the X coordinate needs to be supplied. Otherwise, LOCATION should be set to a two-element vector [X, Y] for two-dimensional graphics or [X, Y, Z] for three-dimensional graphics. If STYLE is currently "None", then setting the LOCATION will automatically set the STYLE to "Manual".
NAME	The name of the graphic.
SNAP	Set to 1 to snap the crosshair to the nearest Plot data point. For other graphics this property is ignored. The default is 1.
STYLE	An integer or string giving the crosshair style. Possible values are: 0 - "None" - never draw the crosshair. This is the default for all graphics except 2D plots. 1 - "Manual" - draw the crosshair using the LOCATION property. 2 - "Auto" - automatically draw the crosshair. This is the default for 2D plots.
THICK	The thickness of the lines. The default is 1.
TRANSPARENCY	The percent transparency of the lines. The default is 50.
UVALUE	An IDL variable of any data type.

For example, use the CROSSHAIR property to draw a crosshair on an image:

im = IMAGE(/TEST, TRANSPARENCY=50, AXIS_STYLE=2)

c = im.CROSSHAIR

c.COLOR = 'red'

c.THICK = 2

c.LOCATION = [300, 200]

See Creating Functions to Control Mouse Events for a more detailed crosshair example.

DIRECTION_CONVENTION

Set this property to indicate the convention to be used when displaying streamline directions. Possible values are:

0 or "Polar" - This describes the direction counterclockwise from X axis, and is the usual physics convention (the default).
1 or "Meteorological" - This describes the direction from which the wind is blowing, and uses terms such as northerly, westerly, and so on.
2 or "Wind" - This describes the wind azimuth (the direction towards which the wind is blowing), and uses terms such as southward, eastward, and so on.

Note: This property does not change the visual appearance of the streamlines - only the direction that is reported in the window's status bar is affected.

FONT_COLOR

Set this property to a string or RGB vector that specifies the text color for the title and axes (if present). The default value is "black".

FONT_NAME

Set this property equal to a string specifying the IDL or system font for the title and axes (if present). The default value is "DejaVuSans"..

FONT_SIZE

Set this property equal to an integer specifying the font size for the title and axes (if present). The default value is 9 points for the axis text and 11 points for the title.

FONT_STYLE

Set this property equal to an integer or a string specifying the font style for the title and axes (if present). Allowed values are:

Integer	String	Resulting Style
0	"Normal" or "rm"	Default (roman)
1	"Bold" or "bf"	Bold
2	"Italic" or "it"	Italic
3	"Bold italic" or "bi"	Bold italic

GRID_UNITS

Set this property to a string or integer specifying the units for the streamline grid. This property applies only when a map projection is inserted. It has the following values:

0 or "" - None. The grid is in arbitrary units that are not tied to a map projection. The streamlines will not be warped to the current map projection.
1 or "m" or "meters" - Meters. The grid is in meters, and is tied to a particular map projection. The streamlines will be warped to the current map projection.
2 or "deg" or "degrees" - Degrees. The grid is in degrees longitude/latitude, and will be automatically warped to the current map projection.

HIDE

Set this property to 1 to hide the graphic. Set HIDE to 0 to show the graphic.

NAME

A string that specifies the name of the graphic. The name can be used to retrieve the graphic using the brackets array notation. If NAME is not set then a default name is chosen based on the graphic type.

POSITION

Set this property to a four-element vector that determines the position of the graphic within the window. The coordinates [X₁, Y₁, X₂, Y₂] define the lower left and upper right corners of the graphic. Coordinates are expressed in normalized units ranging from 0.0 to 1.0. On creation, if the DEVICE keyword is set, the units are given in device units (pixels).

Note: After creation, you can set the POSITION to either a two or four-element vector. If two elements are provided, the center of the graphic will be translated to that position. If four elements are provided, the graphics will be translated and scaled to fit the position.

RGB_TABLE

The number of the predefined IDL color table, or a 3 x 256 or 256 x 3 byte array containing color values to use for the color palette. This color palette is used when the AUTO_COLOR property is set. The default is to use a grayscale ramp.

STREAMLINE_NSTEPS

Set this property to an integer giving the number of steps to take for each streamline. The default is 100.

STREAMLINE_STEPSIZE

Set this property to a floating point value giving the normalized step size for each step in a streamline. The default is 0.2.

THICK

Set this property to a value between 0 and 10 that specifies the thickness of the streamlines. A thickness of 0 displays a thin hairline on the chosen device. The default value is 1.

TITLE

Set this property to a string specifying a title. The title properties may be modified using FONT_COLOR, FONT_NAME, FONT_SIZE, and FONT_STYLE. After creation the TITLE property may be used to retrieve a reference to the title text object, and the TEXT properties may be used to modify the title object.

You can add Greek letters and mathematical symbols using a TeX-like syntax, enclosed within a pair of "$" characters. See Adding Mathematical Symbols and Greek Letters to the Text String for details.

TRANSPARENCY

An integer between 0 and 100 that specifies the percent transparency of the graphic. The default value is 0.

UVALUE

Set this property to an IDL variable of any data type.

WINDOW (Get Only)

This property retrieves a reference to the WINDOW object which contains the graphic.

WINDOW_TITLE

Set this property to the title of the IDL Graphic window. The title is displayed in the window's title bar.

X_STREAMPARTICLES

If STREAMLINES is set, then set this property to an integer giving the number of streamline particles in the x direction. The default is 25. This property is ignored for arrows or wind barbs.

Y_STREAMPARTICLES

If STREAMLINES is set, then set this property to an integer giving the number of streamline particles in the y direction. The default is 25. This property is ignored for arrows or wind barbs.

XRANGE

A two-element vector giving the X data range to streamline. The default behavior is to streamline the entire data range.

YRANGE

A two-element vector giving the Y data range to streamline. The default behavior is to streamline the entire data range.

ZVALUE

A scalar value to be used as the z-coordinate for the entire streamline. By default, 0.0 is used as the z-coordinate.

Version History

8.0	Introduced
8.1	Added the following properties: CROSSHAIR, UVALUE, [XYZ]SHOWTEXT, [XYZ]STYLE The THICK property was changed to accept a value between 0 and 10. Added the following methods: Delete, GetData, GetValueAtLocation, MapForward, MapInverse, SetData
8.2	Added AXES, BACKGROUND_COLOR, BACKGROUND_TRANSPARENCY, CLIP properties.
8.2.1	Added ANTIALIAS property. [XYZ]TICKUNITS accepts exponent as a value.
8.2.2	Change POSITION from a keyword to a property.
8.6	Changed default font name and font size.

Product	IDL

Version	9.0

STREAMLINE

Example

Additional Examples

Syntax

Keywords

Properties

Methods

Return Value

Arguments

U

V

X

Y

Keywords

AXIS_STYLE

BUFFER

CURRENT

DEVICE

DIMENSIONS

LAYOUT

LOCATION

MARGIN

NO_TOOLBAR

NODATA

OVERPLOT

WIDGETS

Properties

ANTIALIAS

ARROW_COLOR

ARROW_OFFSET

ARROW_SIZE

ARROW_THICK

ARROW_TRANSPARENCY

ASPECT_RATIO

AUTO_COLOR

AUTO_RANGE

AXES (Get Only)

BACKGROUND_COLOR

BACKGROUND_TRANSPARENCY

CLIP

COLOR

CROSSHAIR (Get Only)

DIRECTION_CONVENTION

FONT_COLOR

FONT_NAME

FONT_SIZE

FONT_STYLE

GRID_UNITS

HIDE

NAME

POSITION

RGB_TABLE

STREAMLINE_NSTEPS

STREAMLINE_STEPSIZE

THICK

TITLE

TRANSPARENCY

UVALUE

WINDOW (Get Only)

WINDOW_TITLE

X_STREAMPARTICLES

Y_STREAMPARTICLES

XRANGE

YRANGE

ZVALUE

Version History

See Also

Featured Help Article