TrainLocalOutlierFactor Task

This task detects the samples that have a substantially lower density than its neighbors and labels the detections as anomalies.

For background on the algorithm used, see Local Outlier Factor Classification.

Example

; Start the application

e = ENVI()

; Open an input raster file

RasterFile = Filepath('qb_boulder_msi', Subdir=['data'], $

  Root_Dir=e.Root_Dir)

Raster = e.OpenRaster(RasterFile)

; Get the Spectral Index task from the catalog of ENVITasks

SpectralTask=ENVITask('SpectralIndex')

; Define inputs

SpectralTask.INDEX = 'Normalized Difference Vegetation Index'

SpectralTask.INPUT_RASTER = Raster

; Run the task

SpectralTask.Execute

; Get the Image Threshold ROI task from the catalog of ENVITasks

ThresholdROITask=ENVITask('ImageThresholdToROI')

; Define inputs

ThresholdROITask.INPUT_RASTER = SpectralTask.OUTPUT_RASTER

ThresholdROITask.ROI_NAME = 'Water'

ThresholdROITask.ROI_COLOR = [0, 0, 255]

ThresholdROITask.THRESHOLD = [-1, -0.10000000149012, 0]

; Run the task

ThresholdROITask.Execute

; Get the statistics task from the catalog of ENVITasks

StatsTask = ENVITask('NormalizationStatistics')

; Define inputs

StatsTask.INPUT_RASTERS = Raster

; Run the task

StatsTask.Execute

; Get the data prep task from the catalog of ENVITasks

DataPrepTask = ENVITask('MLTrainingDataFromROIs')

; Define inputs

DataPrepTask.INPUT_RASTER = Raster

DataPrepTask.INPUT_ROI = ThresholdROITask.OUTPUT_ROI

DataPrepTask.BACKGROUND_LABELS = []

DataPrepTask.NORMALIZE_MIN_MAX = StatsTask.Normalization

DataPrepTask.Execute

; Get the training task from the catalog of ENVITasks

TrainTask = ENVITask('TrainLocalOutlierFactor')

; Define inputs

TrainTask.INPUT_RASTER = DataPrepTask.OUTPUT_RASTER

; Run the task

TrainTask.Execute

; Output model metadata

outputModelUri = TrainTask.OUTPUT_MODEL_URI

print, 'Model URI: ' + outputModelUri

outputModel = TrainTask.OUTPUT_MODEL

print, outputModel.Attributes

Syntax

Result = ENVITask('TrainLocalOutlierFactor')

Input parameters (Set, Get): INPUT_RASTERS, LEAF_SIZE, MODEL_DESCRIPTION, MODEL_NAME, MODEL_VERSION, OUTPUT_MODEL_URI

Output parameters (Get only): OUTPUT_MODEL

Parameters marked as "Set" are those that you can set to specific values. You can also retrieve their current values any time. Parameters marked as "Get" are those whose values you can retrieve but not set.

Input Parameters

INPUT_RASTERS (required)

Specify one or more preprocessed training rasters to be used for training.

LEAF_SIZE (optional)

Specify the leaf size. Changing the leaf size can affect the speed of construction and query, as well as the memory required to store the tree. The optimal value depends on the nature of the problem. The default is 30.

MODEL_DESCRIPTION (optional)

Specify the purpose of the model.

MODEL_NAME (optional)

Specify the name of the model. The default is Local Outlier Factor Anomaly Detector.

MODEL_VERSION (optional)

Specify a semantic version format (MAJOR.MINOR.PATCH) for the trained model (for example, 1.0.0). The version may indicate the following:

MAJOR: Breaking changes to the model
MINOR: Compatibility or new features
PATCH: Minor adjustments

OUTPUT_MODEL_URI (optional)

Specify a string with the fully qualified filename and path of the associated OUTPUT_MODEL. If you do not specify this parameter, or set it to an exclamation symbol (!), a temporary file will be created.

Output Parameters

OUTPUT_MODEL

This is a reference to the output model file.

Methods

Execute

Parameter

ParameterNames

See ENVI Help for details on these ENVITask methods.

Properties

DESCRIPTION

DISPLAY_NAME

NAME

REVISION

See the ENVITask topic in ENVI Help for details.

Version History

Machine Learning 2.0	Introduced
Machine Learning 6.2	Added the MODEL_VERSION and OUTPUT_MODEL_URI parameters