This task executes the Isolation Forest anomaly detection algorithm against the provided input training rasters. The IsolationForest task isolates detections by randomly selecting a feature, then randomly selecting a split value between the maximum and minimum values of the selected feature.

For background on the algorithm used, see Isolation Forest Classification.

Example

; Start the application
e = ENVI()
 
; Open an input raster file
RasterFile = Filepath('qb_boulder_msi', Subdir=['data'], $
  Root_Dir=e.Root_Dir)
Raster = e.OpenRaster(RasterFile)
 
; Get the Spectral Index task from the catalog of ENVITasks
SpectralTask=ENVITask('SpectralIndex')
 
; Define inputs
SpectralTask.INDEX = 'Normalized Difference Vegetation Index'
SpectralTask.INPUT_RASTER = Raster
 
; Run the task
SpectralTask.Execute
 
; Get the Image Threshold ROI task from the catalog of ENVITasks
ThresholdROITask=ENVITask('ImageThresholdToROI')
 
; Define inputs
ThresholdROITask.INPUT_RASTER = SpectralTask.OUTPUT_RASTER
ThresholdROITask.ROI_NAME = 'Water'
ThresholdROITask.ROI_COLOR = [0, 0, 255]
ThresholdROITask.THRESHOLD = [-1, -0.10000000149012, 0]
 
; Run the task
ThresholdROITask.Execute
 
; Get the statistics task from the catalog of ENVITasks
StatsTask = ENVITask('NormalizationStatistics')
 
; Define inputs
StatsTask.INPUT_RASTERS = Raster
 
; Run the task
StatsTask.Execute
 
; Get the data prep task from the catalog of ENVITasks
DataPrepTask = ENVITask('MLTrainingDataFromROIs')
 
; Define inputs
DataPrepTask.INPUT_RASTER = Raster
DataPrepTask.INPUT_ROI = ThresholdROITask.OUTPUT_ROI
DataPrepTask.BACKGROUND_LABELS = []
DataPrepTask.NORMALIZE_MIN_MAX = StatsTask.Normalization
DataPrepTask.Execute
 
; Get the training task from the catalog of ENVITasks
TrainTask = ENVITask('TrainIsolationForest')
 
; Define inputs
TrainTask.INPUT_RASTER = DataPrepTask.OUTPUT_RASTER
TrainTask.NUM_ESTIMATORS = 100
 
; Run the task
TrainTask.Execute
 
; Output model metadata
outputModelUri = TrainTask.OUTPUT_MODEL_URI
print, 'Model URI: ' + outputModelUri
 
outputModel = TrainTask.OUTPUT_MODEL
print, outputModel.Attributes

Syntax

Result = ENVITask('TrainIsolationForest')

Input properties (Set, Get): BALANCE_CLASSES, INPUT_RASTERS, MODEL_NAME, MODEL_DESCRIPTION, NUM_ESTIMATORS, OUTPUT_MODEL_URI

Output properties (Get only): OUTPUT_MODEL

Properties marked as "Set" are those that you can set to specific values. You can also retrieve their current values any time. Properties marked as "Get" are those whose values you can retrieve but not set.

Methods

This task inherits the following methods from ENVITask. See the ENVITask topic in ENVI Help.

  • AddParameter
  • Execute
  • Parameter
  • ParameterNames
  • RemoveParameters

Properties

This task inherits the following properties from ENVITask:

COMMUTE_ON_DOWNSAMPLE

COMMUTE_ON_SUBSET

DESCRIPTION

DISPLAY_NAME

NAME

REVISION

See the ENVITask topic in ENVI Help for details.

This task also contains the following properties:

BALANCE_CLASSES (optional)

Specify whether all classes should be considered equal during training. This helps to account for classes with few samples compared to classes with many samples.

INPUT_RASTERS (required)

Specify one or more preprocessed training rasters to be used for training.

MODEL_NAME (optional)

Specify the name of the model. The default is Isolation Forest Anomaly Detector.

MODEL_DESCRIPTION (optional)

Specify the purpose of the model.

NUM_ESTIMATORS (optional)

Specify the number of decision trees to use. The estimators are the predictors of the algorithm. The default is 100.

OUTPUT_MODEL (required)

This is a reference to the output model file.

OUTPUT_MODEL_URI (optional)

Specify a string with the fully qualified filename and path of the associated OUTPUT_MODEL. If you do not specify this property, or set it to an exclamation symbol (!), a temporary file will be created.

Version History

Deep Learning 2.0

Introduced

See Also

ENVI Machine Learning Algorithms Background, TrainBirch Task, TrainExtraTrees Task, TrainKNeighbors Task, TrainLinearSVM Task, TrainLocalOutlierFactor Task, TrainMiniBatchKMeans Task, TrainNaiveBayes Task, TrainRandomForest Task, TrainRBFSVM Task